; Load DUS-III from the tape.


; Set up the log(s).

set -N console debug=BURSTWRITE-debug.log
set -N console log=BURSTWRITE.log

set imba debug=csrw;data
set gic  debug
set cpp  debug
set dc   debug=cmd;inco;state


; Establish the initial environment.

echo
echo Configuring the simulation environment.

set CPU 512K,CIS

set console DEL=177

set IMBA ENABLED

break delay 30 milliseconds

attach DC0 scratch.7933.disc


echo
echo
echo -----------------------------
echo Diagnostic Utility System III
echo -----------------------------
echo
echo Loading DUS-III.


; Cold load the DUS-III tape.

attach -e -r MS0 DUS-III.tape
boot MS0


echo
echo Configuring the diagnostic.

deposit SWCH 2


; Load and start the diagnostic.
;
; The diagnostic loads from tape and then waits for a <CR>.

echo
echo Starting the diagnostic.

reply "\r" delay 2 seconds

go until "\r\n:" ; reply "AID\r"


; do a burst-mode LOCWRITE on device 0 unit 0
;
; CC(0) = --0DH (Request Status opcode)
; CC(1) = --18H (Set Length opcode)
; CC(2) = 0000H \
; CC(3) = 0300H / 768 bytes
; CC(4) = 02--H (Locate and Write opcode)
; CC(5) = 3C01H (Set Burst Last opcode, 1 block)

; Line 10
go until "\r\n> " ; reply "DB AA,10,0\r"
go until "\r\n> " ; reply "DB BB,40,0\r"
go until "\r\n> " ; reply "DB CC,10,0\r"
go until "\r\n> " ; reply "DB DD,768,!1111\r"
go until "\r\n> " ; reply "ASSIGN CC(0),!0D,!18,!0000,!0300,!0200,!3C01\r"
go until "\r\n> " ; reply "ASSIGN DD(128),!2222\r"
go until "\r\n> " ; reply "ASSIGN DD(256),!3333\r"
go until "\r\n> " ; reply "LET CHANNEL:=11,DEVICE:=0\r"
go until "\r\n> " ; reply "BSIO ZZ\r"
go until "\r\n> " ; reply "DSJ 110\r            . QSTAT REPORTING\r"
; Line 110
go until "\r\n> " ; reply "WR !5,CC(0),1,,R     . REQUEST STATUS COMMAND\r"
go until "\r\n> " ; reply "WAIT\r"
go until "\r\n> " ; reply "RR !E,BB(0),20       . REQUEST STATUS EXECUTION\r"
go until "\r\n> " ; reply "WAIT\r"
go until "\r\n> " ; reply "DSJ 160\r            . QSTAT REPORTING\r"
; Line 160
go until "\r\n> " ; reply "WR !5,CC(5),2        . SET BURST COMMAND\r"
go until "\r\n> " ; reply "WAIT\r"
go until "\r\n> " ; reply "DSJ 190\r            . QSTAT REPORTING\r"
; Line 190
go until "\r\n> " ; reply "WR !5,CC(1),6,,R     . LOCWRITE COMMAND\r"
go until "\r\n> " ; reply "WAIT\r"
go until "\r\n> " ; reply "WB !E,DD(0),768,256  . LOCWRITE EXECUTION (BURST)\r"
go until "\r\n> " ; reply "JUMP 240             . END ON COUNT\r"
go until "\r\n> " ; reply "JUMP 200             . END ON BURST\r"
go until "\r\n> " ; reply "WAIT\r"             
go until "\r\n> " ; reply "DSJ 260,260          . QSTAT REPORTING\r"
; Line 260
go until "\r\n> " ; reply "IN H\r"
go until "\r\n> " ; reply "RSIO\r"
go until "\r\n> " ; reply "END\r"

go until "\r\n> " ; reply "RUN\r"

; Exit

go until "\r\n> " ; reply "EXIT\r"
go until "?"      ; reply "YES\r"

go until "\r\n:"

exit